ऐसा लगता है कि आप गतिशील रूप से करने के लिए अपने उत्पादन चाहते हैं प्लॉट किए जा रहे डेटा में आकार में समायोजित करें। यहाँ एक स्क्रिप्ट है कि करता है कि:
#!/usr/bin/env gnuplot
# don't make any output just yet
set terminal unknown
# plot the data file to get information on ranges
plot 'data.dat' title 'My Moneys'
# span of data in x and y
xspan = GPVAL_DATA_X_MAX - GPVAL_DATA_X_MIN
yspan = GPVAL_DATA_Y_MAX - GPVAL_DATA_Y_MIN
# define the values in x and y you want to be one 'equivalent:'
# that is, xequiv units in x and yequiv units in y will make a square plot
xequiv = 100
yequiv = 250
# aspect ratio of plot
ar = yspan/xspan * xequiv/yequiv
# dimension of plot in x and y (pixels)
# for constant height make ydim constant
ydim = 200
xdim = 200/ar
# set the y tic interval
set ytics 100
# set the x and y ranges
set xrange [GPVAL_DATA_X_MIN:GPVAL_DATA_X_MAX]
set yrange [GPVAL_DATA_Y_MIN:GPVAL_DATA_Y_MAX]
# set the labels
set title 'Dollars in buckets'
set xlabel 'number'
set ylabel 'Dollars'
set terminal png size xdim,ydim
set output 'test.png'
set size ratio ar
set style data linespoints
replot
इन उदाहरण डेटा के लिए:
0 50
50 150
100 400
150 500
200 300
मैं निम्नलिखित साजिश:
यह एकदम सही ढंग से, वर्ग के बारे में है हो (मैंने x में 100 इकाइयों को वाई में 250 इकाइयों के बराबर परिभाषित किया है, और डेटा सीमा [[0,200), (50,500)]) है। अगर मैं एक और डेटा बिंदु (400,300) जोड़ने के लिए, आउटपुट फ़ाइल के रूप में उम्मीद व्यापक है,:
अपने अन्य सवाल का जवाब करने के लिए, आप y टिक वेतन वृद्धि इस प्रकार सेट कर सकते हैं:
set ytics <INCREMENT>
उपरोक्त लिपि एक उदाहरण देता है।
साइड नोट: टर्मिनल कमांड में आकार को परिभाषित करना ('टर्मिनल पीएनजी आकार सेट करें ... ') वास्तविक आउटपुट फ़ाइल के आकार को परिभाषित करता है, और' सेट आकार अनुपात 'आदेश आउटपुट के क्षेत्र के पहलू अनुपात को सेट करता है जहां साजिश प्लॉट किया गया है। मैंने यह सुनिश्चित करने के लिए दोनों किया कि पहलू अनुपात सुसंगत रहेगा। –
andyras