निर्देशिका में ESY एक्सटेंशन के साथ सभी फ़ाइलों की सूची कैसे प्राप्त करें?

Question

वीबीए में, मैं एक विशिष्ट निर्देशिका में एक विशिष्ट एक्सटेंशन के साथ सभी फ़ाइलों की एक सूची कैसे प्राप्त करूं?

मैं, Application.FileSearch ऐसा करने में असमर्थ हूँ क्योंकि मैं Excel 2007

Answer 1

आपकी टिप्पणी के जवाब में "तो मुझे इसे चलाने के लिए कितनी बार पता है?", यह उदाहरण तब तक चलता है जब तक यह उन सभी फ़ाइलों को सूचीबद्ध नहीं करता है जिनके नाम strPattern से मेल खाते हैं। strFolder निरंतर बदलें।

Public Sub ListESY() 
Const strFolder As String = "C:\SomeFolder\" 
Const strPattern As String = "*.ESY" 
Dim strFile As String 
strFile = Dir(strFolder & strPattern, vbNormal) 
Do While Len(strFile) > 0 
    Debug.Print strFile '<- view this in Immediate window; Ctrl+g will take you there 
    strFile = Dir 
Loop 
End Sub 

Answer 2

डिर उपयोग कर रहा हूँ ("C:। \ YourPath \ * ESY", vbNormal) ESY विस्तार के साथ पहली फ़ाइल देता है। प्रत्येक बाद की कॉल Dir() को अगली बार लौटाती है।

Answer 3

वैकल्पिक विकल्प: वस्तुओं की FileSystemObject परिवार के लिए "माइक्रोसॉफ्ट स्क्रिप्टिंग रनटाइम" पुस्तकालय (उपकरण में यह जाँच ... संदर्भ) का उपयोग करें। कुछ निम्न की तरह, शायद:

Public Function ESYFileCount(dir_path as String) as Long 

Dim fil As File 

    With New FileSystemObject 
     With .GetFolder(dir_path) 
      For Each fil In .Files 
       If LCase(Right(fil.Name, 4)) = ".esy" Then 
        ESYFileCount = ESYFileCount + 1 
       End If 
      Next 
     End With   
    End With 

End Function 

Answer 4

निम्न कोड FileSystemObject का उपयोग करने से लगभग 19 गुना तेज चलता है। मेरी मशीन पर, तीन अलग-अलग डैक्टरीज़ में 4000 फाइलों को ढूंढने से फाइलसिस्टम ऑब्जेक्ट का उपयोग करके 1.57 सेकेंड लगे, लेकिन इस कोड का उपयोग करके केवल 0.08 सेकेंड।

Public Function CountFilesWithGivenExtension(_ 
      i_strFolderWithTerminalBackslant As String, _ 
      i_strExtensionIncludingPeriod As String _ 
     ) As Long 

     If Len(Dir$(i_strFolderWithTerminalBackslant & "*" _ 
      & i_strExtensionIncludingPeriod)) > 0 Then 

      CountFilesWithGivenExtension = 1 

      While Len(Dir$) > 0 

      CountFilesWithGivenExtension = _ 
        CountFilesWithGivenExtension + 1 

      DoEvents 

      Wend 
     Else 
      CountFilesWithGivenExtension = 0 
     End If 

    End Function 

नमूना उपयोग:

Debug.Print CountFilesWithGivenExtension("C:\", ".ex*") 

("DoEvents" आवश्यक नहीं है, लेकिन आप रोकें उपयोग करने के लिए/तोड़ अगर जरूरत अनुमति देता है।)