10
में Web.Config से कनेक्शन स्ट्रिंग पढ़ें मेरे पास एक एएसपी-फ़ाइल है। दरअसल मैं अपनी फाइल में कनेक्शन के साथ डेटाबेस से कनेक्ट करता हूं।ASP.Classic
sConnString = "Driver={SQL Server}; Server=localhost; Database=DB"
क्या वेब से कनेक्शन स्ट्रिंग को पढ़ने का कोई तरीका है? कॉनफिग?
संपादित करें:
के साथ काम करने समझ गया:
' Imports a connection string from an xml file (usually web.config)
Function ImportConnectionString(webConfig, attrName, reformatDSN)
Dim oXML, oNode, oChild, oAttr, dsn
Set oXML=Server.CreateObject("Microsoft.XMLDOM")
oXML.Async = "false"
oXML.Load(Server.MapPath(webConfig))
Set oNode = oXML.GetElementsByTagName("connectionStrings").Item(0)
Set oChild = oNode.GetElementsByTagName("add")
' Get the first match
For Each oAttr in oChild
If oAttr.getAttribute("name") = attrName then
dsn = oAttr.getAttribute("connectionString")
If reformatDSN Then
' Optionally reformat the connection string (adjust as needed)
dsn = Replace(dsn, "User ID=", "UID=")
dsn = Replace(dsn, "Password=", "PWD=")
dsn = Replace(dsn, "Data Source=", "Server=")
dsn = Replace(dsn, "Initial Catalog=", "Database=")
dsn = Replace(dsn, "Persist Security Info=True;", "")
dsn = "Provider=MSDASQL;Driver={SQL Server};" & dsn
End If
ImportConnectionString = dsn
Exit Function
End If
Next
End Function
उपयोग:
dsn = ImportConnectionString("..\web.config", "ConnectionStringName", false)
sql = "SELECT * FROM MyTable"
Set oConn = Server.CreateObject("ADODB.Connection")
Set oRS = Server.CreateObject("ADODB.RecordSet")
oConn.Open dsn
oRS.Open sql, oConn
If NOT oRS.EOF Then
oRS.MoveFirst
Do
Response.Write(" " & oRS("Column1") & "<br/>")
oRS.MoveNext
Loop Until oRS.EOF
End If
मदद
धन्यवाद लिंक मुझे मदद की – Paks
बहुत मैंने यह भी पाया [यह पेज] (http://www.c-sharpcorner.com/UploadFile/sd_patel/WebConfigInASPNet11242005061608AM/WebConfigInASPNet.aspx) से पता चलता है कि कैसे से एक कनेक्शन स्ट्रिंग को निकालने के लिए web.config – mfeineis
@vanhelgen वह पृष्ठ जो आपने लिंक किया है वह वही कर रहा है जो उसके उत्तर में वर्णित है। – crush