कार्यालय 2013 एक्सेल .PutInClipboard अलग है?

Question

मैं क्लिपबोर्ड में एक सादा पाठ स्ट्रिंग है कि मैं इस तरह के रूप में किसी अन्य कार्यक्रम में चिपका सकते हैं डाल करने के लिए साल के लिए एक नियमित उपयोग किया है:

targetData.SetText "This is a plain text string" 
targetData.PutInClipboard 

जब मैं एक्सेल कार्यालय 2013 में इस का उपयोग डेटा में नहीं है क्लिपबोर्ड और इसलिए मैं इसे पेस्ट नहीं कर सकता। यह पहले के संस्करणों में कभी नहीं हुआ था।

करीब निरीक्षण के तहत मैं पाया है कि स्ट्रिंग क्लिपबोर्ड लेकिन जैसा कि "सिस्टम स्ट्रिंग" जाना है, लेकिन नहीं "पाठ" या "यूनिकोड टेक्स्ट" के रूप में।

लेकिन ... समय यह acutally काम करता है के रूप में यह "पाठ" के रूप में क्लिपबोर्ड में स्ट्रिंग डाल चाहिए का लगभग 10%।

कोई विचार ??

Answer 1

आप जोड़ना चाहिए अपने संदर्भ के लिए "माइक्रोसॉफ्ट 2.0 वस्तु पुस्तकालय का निर्माण करती है" तो आप इस सुविधा का उपयोग कर सकते हैं। आप Excel/डेवलपर/दृश्य बुनियादी (या अपने VBE मॉड्यूल) पर जाकर ऐसा कर सकते हैं और उपकरणों/संदर्भ का चयन ब्राउज़ में और फिर "FM20.dll" फ़ाइल के लिए अपने system32 फ़ोल्डर खोज में और उसके बाद में इस फ़ाइल का चयन करके संदर्भ सूची का अंत "माइक्रोसॉफ्ट फॉर्म 2.0 ऑब्जेक्ट लाइब्रेरी" दिखाई देगा। इसे सक्रिय करें। अब बातें पुराने समय के रूप में अच्छा कर रहे हैं;)

Answer 2

user2140261 की टिप्पणी सही समाधान है:

How to: Send Information to the Clipboard

(निम्नलिखित बस ऊपर के लिंक से कॉपी किया जाता है)

हैं

: यदि आप एक फार्म पर सक्रिय नियंत्रण की सामग्री की प्रतिलिपि या क्लिपबोर्ड पर रिपोर्ट करने की आवश्यकता है, आप केवल इस कोड की आवश्यकता

हालांकि, इस प्रतिस्थापन आप अपने पुराने दिनचर्या के लिए की जरूरत है:

1. एक मॉड्यूल बनाएँ, नाम यह "WinAPI" या कुछ और, यह इस कोड डाल:

Declare Function GlobalUnlock Lib "kernel32" (ByVal hMem As Long) As Long 
Declare Function GlobalLock Lib "kernel32" (ByVal hMem As Long) As Long 
Declare Function GlobalAlloc Lib "kernel32" (ByVal wFlags As Long, ByVal dwBytes As Long) As Long 
Declare Function CloseClipboard Lib "User32"() As Long 
Declare Function OpenClipboard Lib "User32" (ByVal hwnd As Long) As Long 
Declare Function EmptyClipboard Lib "User32"() As Long 
Declare Function lstrcpy Lib "kernel32" (ByVal lpString1 As Any, ByVal lpString2 As Any) As Long 
Declare Function SetClipboardData Lib "User32" (ByVal wFormat As Long, ByVal hMem As Long) As Long 

Public Const GHND = &H42 
Public Const CF_TEXT = 1 
Public Const MAXSIZE = 4096 

2. मॉड्यूल में जहां अपने पुराने नियमित परिभाषित किया गया है, इस कोड के साथ अपने पुराने दिनचर्या बदल देते हैं:

Function ClipBoard_SetData(MyString As String) 
    Dim hGlobalMemory As Long, lpGlobalMemory As Long 
    Dim hClipMemory As Long, X As Long 

    ' Allocate moveable global memory. 
    '------------------------------------------- 
    hGlobalMemory = GlobalAlloc(GHND, Len(MyString) + 1) 

    ' Lock the block to get a far pointer 
    ' to this memory. 
    lpGlobalMemory = GlobalLock(hGlobalMemory) 

    ' Copy the string to this global memory. 
    lpGlobalMemory = lstrcpy(lpGlobalMemory, MyString) 

    ' Unlock the memory. 
    If GlobalUnlock(hGlobalMemory) <> 0 Then 
     MsgBox "Could not unlock memory location. Copy aborted." 
     GoTo OutOfHere2 
    End If 

    ' Open the Clipboard to copy data to. 
    If OpenClipboard(0&) = 0 Then 
     MsgBox "Could not open the Clipboard. Copy aborted." 
     Exit Function 
    End If 

    ' Clear the Clipboard. 
    X = EmptyClipboard() 

    ' Copy the data to the Clipboard. 
    hClipMemory = SetClipboardData(CF_TEXT, hGlobalMemory) 

OutOfHere2: 

    If CloseClipboard() = 0 Then 
     MsgBox "Could not close Clipboard." 
    End If 

End Function 

3. फिर, इसे इस तरह कहते हैं:

' doesn't work on Windows 8: targetData.SetText "This is a plain text string" 
'doesn't work on Windows 8: targetData.PutInClipboard 
ClipBoard_SetData ("This is a plain text string")