फ़ायरमॉन्की और मालिक के मॉडल का मॉडल संवाद केंद्र दिखा रहा है

Question

मुझे मालिक के रूप में केंद्र में संवाद संवाद प्रदर्शित करने में समस्या है। मॉडल संवाद दिखाने के लिए मेरे कोड है:

procedure TfrmMain.btnOpenSettingsClick(Sender: TObject); 
var 
    sdSettingsDialog: TdlgSettings; 

begin 
    sdSettingsDialog := TdlgSettings.Create(Self); 
    sdSettingsDialog.Position := TFormPosition.poOwnerFormCenter; 

    try 
     sdSettingsDialog.ShowModal; 
    finally 
    sdSettingsDialog.Free; 
    end; 
end; 

भी डिजाइनर में स्थिति संपत्ति को बदलने के लिए कोशिश की, लेकिन यह संवाद केंद्र के लिए लगता है नहीं करता है।

क्या आप मुझे बता सकते हैं कि यहां क्या गलत है?

Answer 1

शोमोडल द्वारा फायरमॉन्की में स्थिति लागू नहीं की गई है। वर्ग सहायक नीचे आप का उपयोग कर सकते हैं: इससे पहले कि आप sdSettingsDialog.UpdateFormPosition फोन ShowModal:

type 
    TFormHelper = class helper for TForm 
    procedure UpdateFormPosition; 
    end; 

procedure TFormHelper.UpdateFormPosition; 
var 
    RefForm: TCommonCustomForm; 
begin 
    RefForm := nil; 

    case Position of 
    // TFormPosition.poScreenCenter: implemented in FMX.Forms (only one) 
    TFormPosition.poOwnerFormCenter: 
     if Assigned(Owner) and (Owner is TCommonCustomForm) then 
     RefForm := Owner as TCommonCustomForm; 
    TFormPosition.poMainFormCenter: 
     RefForm := Application.MainForm; 
    end; 

    if Assigned(RefForm) then 
    begin 
    SetBounds(
     System.Round((RefForm.Width - Width)/2) + RefForm.Left, 
     System.Round((RefForm.Height - Height)/2) + RefForm.Top, 
     Width, Height); 
    end; 
end;