पुनरावृत्ति अपंजीकृत ऐड-इन्स (.xla)

Question

मैं

• में मदद की जरूरत है पता लगाना वर्तमान में खुले एक्सेल ऐड-इन फ़ाइलों के माध्यम से पुनरावृति करने के लिए कैसे (.xla) कि Excel में पंजीकृत नहीं किया गया है का उपयोग करते हुए Tools > Add-ins मेनू पथ।
• अधिक विशेष रूप से, मुझे किसी भी कार्यपुस्तिका में रूचि है जो एड-इन संवाद में प्रकट नहीं होता है, लेकिन ThisWorkbook.IsAddin = True है।

  के रूप में इस प्रकार है .AddIn = True साथ कार्यपुस्तिका नहीं मिलता है कार्यपुस्तिका लूप करने के लिए कोशिश कर रहा है: ऐड-इन्स के माध्यम से लूपिंग ऐड-इन्स हैं कि नहीं मिलता है

  Dim book As Excel.Workbook 
  
  For Each book In Application.Workbooks 
      Debug.Print book.Name 
  Next book 
  

मुद्दा दिखाते पंजीकृत नहीं:

Dim addin As Excel.AddIn 

For Each addin In Application.AddIns 
    Debug.Print addin.Name 
Next addin 

वीबीप्रोजेक्ट संग्रह कार्यों के माध्यम से लूपिंग, लेकिन केवल तभी जब उपयोगकर्ता विशेष रूप से है मैक्रो सुरक्षा सेटिंग्स में विजुअल बेसिक परियोजना के लिए विश्वसनीय पहुँच - जो शायद ही कभी होता है:

Dim vbproj As Object 

For Each vbproj In Application.VBE.VBProjects 
    Debug.Print vbproj.Filename 
Next vbproj 

हालांकि, अगर कार्यपुस्तिका के नाम से जाना जाता है, कार्यपुस्तिका सीधे चाहे वह एक ऐड-इन है की परवाह किए बिना संदर्भित किया जा सकता या नहीं:

Dim book As Excel.Workbook 
Set book = Application.Workbooks("add-in.xla") 

लेकिन उपयोगकर्ता के मैक्रो सुरक्षा सेटिंग्स अगर नाम ज्ञात नहीं है कि इस कार्यपुस्तिका के संदर्भ में प्राप्त करने के लिए ओह, और पर भरोसा नहीं किया जा सकता है?

Answer 1

ऑफिस 2010 की स्थिति के अनुसार एक नया संग्रह .AddIns2 जो .AddIns रूप में ही है, लेकिन यह भी अपंजीकृत .xla प्लग-इन में शामिल हैं।

Dim a As AddIn 
Dim w As Workbook 

On Error Resume Next 
With Application 
    For Each a In .AddIns2 
     If LCase(Right(a.name, 4)) = ".xla" Then 
      Set w = Nothing 
      Set w = .Workbooks(a.name) 
      If w Is Nothing Then 
       Set w = .Workbooks.Open(a.FullName) 
      End If 
     End If 
    Next 
End With 

Answer 2

मैं अभी भी इस समस्या के लिए एक सौहार्द समाधान के लिए देख रहा हूं, लेकिन ऐसा लगता है कि सभी कार्यपुस्तिका खिड़कियों के विंडो ग्रंथों को पढ़ने से सभी खुली कार्यपुस्तिकाओं का संग्रह मिलता है, एड-इन या नहीं:

Public Sub ListAddins() 

Dim ai As AddIn 

    For Each ai In Application.AddIns 
     If Not ai.Installed Then 
      Debug.Print ai.Application, ai.Parent, ai.Name, ai.FullName 
     End If 
    Next 

End Sub 

कोई भी उपयोग:

Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" (ByVal hWnd1 As Long, ByVal hWnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long 
Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" (ByVal hWnd As Long, ByVal lpClassName As String, ByVal nMaxCount As Long) As Long 
Private Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hWnd As Long, ByVal lpString As String, ByVal cch As Long) As Long 

Public Function GetAllOpenWorkbooks() As Collection 

'Retrieves a collection of all open workbooks and add-ins. 

Const EXCEL_APPLICATION_WINDOW As String = "XLDESK" 
Const EXCEL_WORKBOOK_WINDOW  As String = "EXCEL7" 

Dim hWnd    As Long 
Dim hWndExcel   As Long 
Dim contentLength  As Long 
Dim buffer    As String 
Dim bookName   As String 
Dim books    As Collection 

Set books = New Collection 

'Find the main Excel window 
hWndExcel = FindWindowEx(Application.hWnd, 0&, EXCEL_APPLICATION_WINDOW, vbNullString) 

Do 

    'Find next window 
    hWnd = FindWindowEx(hWndExcel, hWnd, vbNullString, vbNullString) 

    If hWnd Then 

     'Create a string buffer for 100 chars 
     buffer = String$(100, Chr$(0)) 

     'Get the window class name 
     contentLength = GetClassName(hWnd, buffer, 100) 

     'If the window found is a workbook window 
     If Left$(buffer, contentLength) = EXCEL_WORKBOOK_WINDOW Then 

      'Recreate the buffer 
      buffer = String$(100, Chr$(0)) 

      'Get the window text 
      contentLength = GetWindowText(hWnd, buffer, 100) 

      'If the window text was returned, get the workbook and add it to the collection 
      If contentLength Then 
       bookName = Left$(buffer, contentLength) 
       books.Add Excel.Application.Workbooks(bookName), bookName 
      End If 

     End If 

    End If 

Loop While hWnd 

'Return the collection 
Set GetAllOpenWorkbooks = books 

End Function 

Answer 3

इस बारे में

क्या?

Answer 4

उपयोग = दस्तावेज़, एक एक्सेल 4 मैक्रो फ़ंक्शन।

Dim Docs As Variant 
Docs = Application.Evaluate("documents(2)") 

यहाँ यह के लिए दस्तावेज़ (उपलब्ध here) है:,

दस्तावेजों
रिटर्न पाठ के रूप में एक क्षैतिज सरणी के रूप में, वर्णमाला क्रम में निर्दिष्ट खुला कार्यपुस्तिका के नाम। खुली कार्यपुस्तिकाओं में हेरफेर करने वाले अन्य कार्यों में उपयोग करने के लिए खुले कार्यपुस्तिकाओं के नाम पुनर्प्राप्त करने के लिए दस्तावेज़ों का उपयोग करें।

सिंटेक्स
दस्तावेजों (type_num, match_text)
Type_num एक नंबर का उल्लेख करने के लिए कि क्या ऐड-इन कार्यपुस्तिका की सरणी में कार्यपुस्तिका, निम्न तालिका के अनुसार शामिल करने के लिए है।

Type_num  Returns 
1 or omitted Names of all open workbooks except add-in workbooks 
2    Names of add-in workbooks only 
3    Names of all open workbooks 

Match_text कार्यपुस्तिका जिनके नाम आप लौटे चाहते हैं और वाइल्डकार्ड वर्ण शामिल कर सकते हैं निर्दिष्ट करता है। यदि match_text छोड़ा गया है, तो दस्तावेज़ सभी खुली कार्यपुस्तिकाओं के नाम लौटाते हैं।

Answer 5

रजिस्ट्री के माध्यम से एक संभावना है? मुझे पता है कि यह आपको एक्सेल का उपयोग करने का एक स्नैपशॉट नहीं देता है, लेकिन एक नया उदाहरण क्या उपयोग करेगा - लेकिन इसके लिए आपको जिस चीज की आवश्यकता है उसके आधार पर, यह काफी अच्छा हो सकता है।

प्रासंगिक चाबियाँ हैं:

'Active add-ins are in values called OPEN* 
HKEY_CURRENT_USER\Software\Microsoft\Office\12.0\Excel\Options 

'Inactive add-ins are in values of their full path 
HKEY_CURRENT_USER\Software\Microsoft\Office\12.0\Excel\Add-in Manager 

Answer 6

मैं addins कि स्थापित कर रहे हैं (और VBE में) के साथ मुद्दों पड़ा है (एक काम के माहौल में) उपयोगकर्ता एक्सेल 2013 को की Addin के माध्यम से उपलब्ध नहीं किया जा रहा।

क्रिस सी से the solution के साथ टिंकरिंग ने एक अच्छा कामकाज दिया।

Dim a As AddIn 
Dim wb As Workbook 

On Error Resume Next 
With Application 
    .DisplayAlerts = False 
     For Each a In .AddIns2 
     Debug.Print a.Name, a.Installed 
      If LCase(Right$(a.Name, 4)) = ".xla" Or LCase(Right$(a.Name, 5)) Like ".xla*" Then 
       Set wb = Nothing 
       Set wb = .Workbooks(a.Name) 
       wb.Close False 
       Set wb = .Workbooks.Open(a.FullName) 
      End If 
     Next 
    .DisplayAlerts = True 
End With