TProc <TObject> TNotifyEvent को

Question

इस post जिसका स्वीकार किए जाते हैं जवाब देने के लिए इसके अलावा बहुत गुप्त रहता है:

@Button1.OnClick := pPointer(Cardinal(pPointer(procedure (sender: tObject) begin ((sender as TButton).Owner as TForm).Caption := 'Freedom to anonymous methods!' end)^) + $0C)^; 

मुझे आश्चर्य है कि मौसम यह एक सरल और सुरुचिपूर्ण तरीका जैसा चिंतन करना संभव है:

Button.OnClick := 
        AnonProc2NotifyEvent (
        procedure (Sender: TObject) 
        begin 
         ((Sender as TButton).Owner as TForm).Caption := 'Freedom to anonymous methods!' 
        end 
        ); 

इतनी के रूप में

उसी उद्देश्य को प्राप्त करने के लिए और जहां AnonProc2NotifyEvent निम्नलिखित हस्ताक्षर के साथ बटन के मालिक का एक तरीका है:

TOwnerOfButton = class(TForm) 
    Button: TButton; 
    ... 
private 
    ... 
protected 
    function AnonProc2NotifyEvent(aProc: TProc<TObject>): TNotifyEvent; 
public 
    ... 
end; 

क्या यह व्यवहार्य है और यदि ऐसा है तो इसे कैसे कार्यान्वित किया जाए?

Answer 1

यह काम आसानी से पर्याप्त करना होगा:

type 
    TNotifyEventWrapper = class(TComponent) 
    private 
    FProc: TProc<TObject>; 
    public 
    constructor Create(Owner: TComponent; Proc: TProc<TObject>); 
    published 
    procedure Event(Sender: TObject); 
    end; 

constructor TNotifyEventWrapper.Create(Owner: TComponent; Proc: TProc<TObject>); 
begin 
    inherited Create(Owner); 
    FProc := Proc; 
end; 

procedure TNotifyEventWrapper.Event(Sender: TObject); 
begin 
    FProc(Sender); 
end; 

function AnonProc2NotifyEvent(Owner: TComponent; Proc: TProc<TObject>): TNotifyEvent; 
begin 
    Result := TNotifyEventWrapper.Create(Owner, Proc).Event; 
end; 

AnonProc2NotifyEvent में Owner पैरामीटर है ताकि आवरण वस्तु के जीवनकाल प्रबंधित किया जा सकता। इस तरह के कुछ के बिना आप TNotifyEventWrapper के उदाहरण रिसाव करेंगे।

Owner के रूप में पास करें, जिस घटक से आप ईवेंट को जोड़ रहे हैं। उदाहरण के लिए:

Button1.OnClick := AnonProc2NotifyEvent(
    Button1, 
    procedure(Sender: TObject) 
    begin 
    (Sender as TButton).Caption := 'Clicked'; 
    end 
); 

तो, जब बटन नष्ट हो जाता है, TNotifyEventWrapper भी नष्ट हो जाएगा। रैपर ऑब्जेक्ट कम से कम तब तक जीवित रहना चाहिए जब तक ऑब्जेक्ट की घटनाओं से संबंधित हो। और इसलिए Button1 की पसंद मालिक के रूप में प्राकृतिक और स्पष्ट है।

Answer 2

संदर्भ के लिए यह है कि क्या मैं पर हो रही है, मैं अध्ययन किया Barry Kelly के ब्लॉग post पहले अतः जैसा कि ऊपर उल्लेख पोस्ट में जिक्र किया गया और इस समाधान के साथ आया था:

function TMainForm.Proc2NotifyEvent(const aProc: TNotifyReference): TNotifyEvent; 
type 
    TVtable = array[0..3] of Pointer; 
    PVtable = ^TVtable; 
    PPVtable = ^PVtable; 
begin 
    TMethod(Result).Code := PPVtable((@aProc)^)^^[3]; 
    TMethod(Result).Data := Pointer((@aProc)^); 
end; 

फिर भी गुप्त लेकिन encapsuled, इसलिए आसान प्रारंभिक विधि की तुलना में कोडर का कार्य।

मैं MethRefToMethPtr और MakeNotify साफ और यह सब एक विधि में डालने की कोशिश की।

सूचना नहीं थी (एक मामूली) विधि के हस्ताक्षर में परिवर्तन, तर्क aProcस्थिरांक बन गया।