क्या चयन के लिए एसक्यूएल% पंक्ति गणना का उपयोग करना संभव है?

Question

नीचे दिया गया कोड एक से अधिक पंक्ति वापस कर सकता है। sql%rowcount लाए गए पंक्तियों की संख्या वापस कर देगा?

select * from emp where empname = 'Justin' and dept='IT' 
if sql%rowcount>0 
    ... 

यह मेरा नमूना proc है; क्या मैं सही तरीके से sql%rowcount का उपयोग कर रहा हूं?

CREATE PROCEDURE Procn(in_Hid IN VARCHAR2,outInststatus OUT VARCHAR2,outSockid IN NUMBER,outport OUT VARCHAR2,outIP OUT VARCHAR2,outretvalue OUT NUMBER) 
AS 
BEGIN 
select INST_STATUS into outInststatus from TINST_child where INST_ID = in_Hid and INST_STATUS = 'Y'; 
if outInststatus = 'Y' then 
    select PORT_NUMBER,STATIC_IP into outport,outIP from TINST where INST_ID = in_Hid and IP_PORT_STATUS = 'Y'; 
    if sql%rowcount >= 1 then 
     select SOCK_ID into outSockid from TINST where PORT_NUMBER = outport AND STATIC_IP = outIP; 
     outretvalue := 0; 
    else 
     outretvalue := -12; 
    end if; 
    EXCEPTION 
    WHEN NO_DATA_FOUND THEN 
    outretvalue := -13; 
end if; 
END; 

Answer 1

अपनी टिप्पणी के आधार पर

2 'का चयन करें' क्वेरी एक से अधिक पंक्तियां देता है, तो मैं ले जाना चाहते हैं पहला वाला और इसके साथ प्रक्रिया

... यह काम करना चाहिए, लेकिन संभवतः आप अपेक्षा नहीं करते हैं, क्योंकि आपने यह परिभाषित नहीं किया है कि 'पहला' का अर्थ क्या है।

CREATE PROCEDURE Procn(in_Hid IN VARCHAR2, outInststatus OUT VARCHAR2, 
    outSockid IN NUMBER, outport OUT VARCHAR2, outIP OUT VARCHAR2, 
    outretvalue OUT NUMBER) 
AS 
BEGIN 
    select INST_STATUS into outInststatus 
    from TINST_child 
    where INST_ID = in_Hid and INST_STATUS = 'Y'; 

    -- no need to check if outInstatus is Y, that's all it can be here 

    -- restricting with `rownum` means you'll get at most one row, so you will 
    -- not get too_many_rows. But it will be an arbitrary row - you have no 
    -- criteria to determine which of the multiple rows you want. And you can 
    -- still get no_data_found which will go to the same exception and set -12 
    select PORT_NUMBER, STATIC_IP into outport, outIP 
    from TINST 
    where INST_ID = in_Hid and IP_PORT_STATUS = 'Y' 
    and rownum < 2; 

    -- no need to check sql%rowcount; it can only be 1 here 

    -- not clear if this can return multiple rows too, and what should happen 
    -- if it can; could use rownum restriction but with the same caveats 
    select SOCK_ID into outSockid 
    from TINST 
    where PORT_NUMBER = outport AND STATIC_IP = outIP; 

    outretvalue := 0; 
EXCEPTION 
    WHEN NO_DATA_FOUND THEN 
     outretvalue := -12; 
END; 

---

exception हैंडलर पूरे block पर लागू होता है।यदि select कथनों में से कोई भी पंक्ति नहीं ढूंढता है, तो no_data_found अपवाद उस ब्लॉक द्वारा संभाला जाएगा और outretvalue-12 पर सेट करेगा।

आप प्रत्येक select के लिए एक अलग outretvalue चाहते हैं तो आपको, उप ब्लॉक में उन्हें लपेट कर सकते हैं अपने खुद के अपवाद संचालन अनुभाग के साथ प्रत्येक:

CREATE PROCEDURE Procn(in_Hid IN VARCHAR2, outInststatus OUT VARCHAR2, 
    outSockid IN NUMBER, outport OUT VARCHAR2, outIP OUT VARCHAR2, 
    outretvalue OUT NUMBER) 
AS 
BEGIN 
    BEGIN 
     select INST_STATUS into outInststatus 
     from TINST_child 
     where INST_ID = in_Hid and INST_STATUS = 'Y'; 
    EXCEPTION 
     WHEN NO_DATA_FOUND THEN 
      outretvalue := -12; 
    END; 

    BEGIN 
     select PORT_NUMBER, STATIC_IP into outport, outIP 
     from TINST 
     where INST_ID = in_Hid and IP_PORT_STATUS = 'Y' 
     and rownum < 2; 
    EXCEPTION 
     WHEN NO_DATA_FOUND THEN 
      outretvalue := -13; 
    END; 

    BEGIN 
     select SOCK_ID into outSockid 
     from TINST 
     where PORT_NUMBER = outport AND STATIC_IP = outIP; 
    EXCEPTION 
     WHEN NO_DATA_FOUND THEN 
      outretvalue := -14; 
    END; 

    outretvalue := 0; 
END; 

आप केवल करने की ज़रूरत है कि फोन करने वाले को पता करने की जरूरत है जो select असफल रहा, और यदि आप वास्तव में कभी भी विफल होने की उम्मीद नहीं करते हैं तो शायद यह अधिक आम है कि अपवाद को पकड़ न लें और कॉलर को कच्चे no_data_found देखें और तय करें कि क्या करना है। निर्भर करता है कि अपवाद की स्थिति आपके और आपके आवेदन के लिए क्या है।

Answer 2

हां, आप SQL%ROWCOUNT का उपयोग कर सकते हैं। यह पीएल/एसक्यूएल में मान्य है।

हालांकि, पीएल/एसक्यूएल में आपकी क्वेरी के परिणाम कहीं कहीं जाने की आवश्यकता है उदा। एक पीएल/एसक्यूएल तालिका में। पीएल/एसक्यूएल परिणाम कभी भी आउटपुट (टर्मिनल, विंडो इत्यादि) को न भेजें। तो SELECT * FROM काम नहीं करेगा।

आपका कोड ऐसा दिखाई दे सकता:

DECLARE 
    TYPE emp_t ...; 
    emp_tab emp_t; 

BEGIN 
    SELECT * 
    BULK COLLECT INTO emp_tab 
    FROM emp 
    WHERE empname = 'Justin' AND dept='IT'; 

    IF sql%rowcount > 0 THEN 
    .. do something ... 
    END IF; 
END; 
/

अद्यतन:

अद्यतन सवाल पता चलता है कि आप कुछ और की तलाश में हैं।

विकल्प 1: अपवाद उपयोग

0 पंक्तियों या 1 से अधिक पंक्ति देखते हैं, तो इन मामलों (त्रुटियों के रूप में) अलग से नियंत्रित किया जाता है:

BEGIN 
    select PORT_NUMBER,STATIC_IP into outport, outIP 
    from TINST 
    where INST_ID = in_Hid AND IP_PORT_STATUS = 'Y'; 

EXCEPTION 
    WHEN NO_DATA_FOUND THEN 
    outretvalue := -12; 
    RETURN; 

    WHEN TOO_MANY_ROWS THEN 
    outretvalue := -13; 
    RETURN; 
END; 

विकल्प 2: उपयोग एकत्रित

समेकन का उपयोग करके, क्वेरी हमेशा एक पंक्ति वापस आ जाएगी। यदि अब स्रोत पंक्ति WHERE खंड से मेल खाती है, तो दोनों परिणाम मान शून्य होंगे। यदि वहां एक से अधिक पंक्तियों का मिलान किया गया है, तो अधिकतम लिया जाएगा।

ध्यान दें कि यह क्वेरी एक पोर्ट नंबर और एक आईपी पता लौटा सकती है जो मूल रूप से एक ही पंक्ति पर नहीं थी।

select MAX(PORT_NUMBER), MAX(STATIC_IP) into outport, outIP 
from TINST 
where INST_ID = in_Hid AND IP_PORT_STATUS = 'Y'; 

IF outport IS NULL OR outIP IS NULL THEN 
    outretvalue := -12; 
    RETURN; 
END IF; 

विकल्प 3: का प्रयोग करें ROWNUM

इस क्वेरी सबसे पहले एक पंक्ति में वापस आती है। कोई पंक्ति कहां खंड का मिलान नहीं हुआ, तो एक अपवाद फेंका और नियंत्रित किया जा करने के लिए की जरूरत है:

BEGIN 
    select PORT_NUMBER, STATIC_IP into outport, outIP 
    from TINST 
    where INST_ID = in_Hid AND IP_PORT_STATUS = 'Y' 
    AND ROWNUM = 1; 

EXCEPTION 
    WHEN NO_DATA_FOUND THEN 
    outretvalue := -12; 
    RETURN; 

END;