क्या कॉफ़ीस्क्रिप्ट में सरणी समानता का परीक्षण करने के लिए एक बेवकूफ तरीका है?

Question

अभिव्यक्ति

[1, 2, 3] == [1, 2, 3] 

Coffeescript में false का आकलन करती है लेकिन वहाँ एक संक्षिप्त, मुहावरेदार सरणी समानता परीक्षण करने के लिए तरीका है?

Answer 1

आप संख्याओं के एरे के साथ काम कर रहे हैं, और आप जानते हैं कि कोई nulls या अपने सरणियों में अपरिभाषित मूल्यों देखते हैं कि, तो आप उन्हें स्ट्रिंग के रूप में तुलना कर सकते हैं:

a = [1, 2, 3] 
b = [1, 2, 3] 

console.log "#{a}" is "#{b}" # true 
console.log '' + a is '' + b # true 

सूचना यह है कि

a = [1, 2, 3] 
b = ['1,2', 3] 

console.log "#{a}" is "#{b}" # true 

आप एक और अधिक मजबूत समाधान चाहते हैं, तो आप उपयोग कर सकते हैं Array#every: इस जैसे ही आप उस नंबर नहीं हैं अन्य बातों के की तुलना सरणियों शुरू टूट जाएगा

arrayEqual = (a, b) -> 
    a.length is b.length and a.every (elem, i) -> elem is b[i] 

console.log arrayEqual [1, 2, 3], [1, 2, 3] # true 
console.log arrayEqual [1, 2, 3], [1, 2, '3'] # false 
console.log arrayEqual [1, 2, 3], ['1,2', 3] # false 

ध्यान दें कि यह पहली बार सरणी की लंबाई की तुलना कर रहा है ताकि arrayEqual [1], [1, 2, 3] सत्य न हो।

Answer 2

यदि आपको Underscore.js निर्भरता पेश करने में कोई बात नहीं है तो आप इसकी कुछ उपयोगिताओं का उपयोग कर सकते हैं। यह बड़े पैमाने पर सुंदर नहीं है, लेकिन मैं सादे coffeescript साथ यह करने के लिए एक आसान तरीका नहीं सोच सकते हैं:

a = [ 1, 2, 3 ] 
b = [ 1, 2, 3 ] 
equal = a.length == b.length and _.all(_.zip(a, b), ([x,y]) -> x is y) 

Answer 3

मैं इस मुहावरेदार पर विचार नहीं होगा, लेकिन यह एक अतिरिक्त पुस्तकालय जोड़े बिना यह करने का एक तरीका हो सकता है :

a = [1, 2, 3, 4] 
b = [22, 3, 4] 

areEqual = true 
maxIndex = Math.max(a.length, b.length)-1 
for i in [0..maxIndex] 
    testEqual = a[i] is b[i] 
    areEqual = areEqual and testEqual 

console.log areEqual 

एक क्लीनर विधि के लिए JavaScript का reduce() फ़ंक्शन का उपयोग किया जाएगा। यह थोड़ा छोटा है लेकिन मुझे यकीन नहीं है कि सभी ब्राउज़रों का समर्थन कम हो जाता है।

a = [1, 3, 4, 5] 
b = [1, 3, 4, 5] 

maxIndex = Math.max(a.length, b.length)-1 
areEqual = true 
[0..maxIndex].reduce (p, c, i, ar) -> areEqual = areEqual and (a[i] is b[i]) 

console.log "areEqual=#{areEqual}" 

Answer 4

मैं Sugar.js का बड़ा प्रशंसक हूं। आपको लगता है कि का उपयोग कर कर रहे हैं तो:

a = [1, 2, 3] 
b = [1, 2, 3] 
Object.equal(a, b) 

Answer 5

निम्नलिखित अच्छा काम करता है और कोई निर्भरता की आवश्यकता है:

arrayEqual = (ar1, ar2) -> 
    JSON.stringify(ar1) is JSON.stringify(ar2) 

Answer 6

यह फ़ंक्शन true अगर सरणियों एक ही लंबाई है और एक ही सूचकांक के साथ सभी मूल्यों एक ही मूल्य है। अगर कोई तर्क एक सरणी नहीं है तो यह एक त्रुटि फेंकता है।

isArray = Array.isArray || (subject) -> 
    toString.call(subject) is '[object Array]' 

compareArrays = (a, b) -> 
    unless isArray(a) and isArray b 
     throw new Error '`arraysAreEqual` called with non-array' 

    return false if a.length isnt b.length 

    for valueInA, index in a 
     return false if b[index] isnt valueInA 

    true