वीबी 6

Question

में संलग्न करने में टेक्स्ट फ़ाइल लिखें (यूटीएफ -8 एन्कोडेड) मुझे वीबी 6 में टेक्स्टफाइल लिखना है। मुझे इसे एपेंडिंग और यूटीएफ -8 एन्कोडेड में करने की ज़रूरत है।

मैंने दो समाधानों की कोशिश की, एक "टेक्स्टस्ट्रीम" और "एडीओडीबी.स्ट्रीम" वाला दूसरा।

पहले एक:

Set fsoFile = fso.OpenTextFile(FileIn(fi), ForAppending, True) 
    fsoFile.WriteLine "<tag>kkkjòòkkkkjlòlk</tag>" 
    fsoFile.Close 

जोड़कर में अच्छा काम करता है, लेकिन मैं यह कैसे लिख सकते हैं utf-8 इनकोडिंग?

दूसरा एक: utf-8 में

Dim ST As ADODB.Stream 

Set ST = New ADODB.Stream 
ST.Mode = adModeReadWrite 
ST.Type = adTypeText 
ST.Charset = "UTF-8" 

ST.Open 
ST.LoadFromFile FileIn(fi) 
ST.Position = ST.Size 
ST.WriteText "<tag>kkkjòòkkkkjlòlk</tag>" 
ST.SaveToFile FileIn(fi) 
ST.Close 

लिखें सही ढंग से, लेकिन मैं केवल "adSaveCreateOverWrite" के साथ जोड़कर लेकिन में फ़ाइल नहीं लिख सकते हैं।

मैं यह कैसे कर सकता हूं? क्या कोई और तरीका है?

बहुत बहुत धन्यवाद।

Answer 1

आप एक API कॉल के साथ बाइनरी आई/ओ गठबंधन UTF-8 में रूपांतरण करने के लिए कर सकते हैं:

Option Explicit 

Private Const CP_UTF8 As Long = 65001 

Private Declare Function WideCharToMultiByte Lib "kernel32" (_ 
    ByVal CodePage As Long, _ 
    ByVal dwFlags As Long, _ 
    ByVal lpWideCharStr As Long, _ 
    ByVal cchWideChar As Long, _ 
    ByVal lpMultiByteStr As Long, _ 
    ByVal cchMultiByte As Long, _ 
    ByVal lpDefaultChar As Long, _ 
    ByVal lpUsedDefaultChar As Long) As Long 

Private Function OpenAppendUTF8(ByVal FileName As String) As Integer 
    OpenAppendUTF8 = FreeFile(0) 
    Open FileName For Binary Access Write As #OpenAppendUTF8 
    Seek #OpenAppendUTF8, LOF(OpenAppendUTF8) + 1 
End Function 

Private Sub WriteUTF8(_ 
    ByVal FNum As Integer, _ 
    ByVal Text As String, _ 
    Optional ByVal NL As Boolean) 

    Dim lngResult As Long 
    Dim UTF8() As Byte 

    If NL Then Text = Text & vbNewLine 
    lngResult = WideCharToMultiByte(CP_UTF8, 0, StrPtr(Text), Len(Text), _ 
            0, 0, 0, 0) 
    If lngResult > 0 Then 
     ReDim UTF8(lngResult - 1) 
     WideCharToMultiByte CP_UTF8, 0, StrPtr(Text), Len(Text), _ 
          VarPtr(UTF8(0)), lngResult, 0, 0 
     Put #FNum, , UTF8 
    End If 
End Sub 

Private Sub Main() 
    Dim F As Integer 

    F = OpenAppendUTF8("test.txt") 
    WriteUTF8 F, "Hello" 
    WriteUTF8 F, ChrW$(&H2026&) 
    WriteUTF8 F, "World", True 
    Close #F 
    MsgBox "Done" 
End Sub 

Answer 2

मैं इसे एएनएसआई को बचाने के लिए के रूप में यह डिफ़ॉल्ट रूप से करता है पसंद करते हैं। इसे नोटपैड के साथ खोलें और इसे यूटीएफ 8 एन्कोडिंग का चयन करें। मैंने पाया कि यह अब तक का सबसे तेज़ तरीका है। और मैं कुछ अन्य कोड, उदाहरण के लिए एक डेटाबेस रूपांतरण के लिए उपयोग करें संलग्न करने के लिए:

Dim fs As Object, a 
Set fs = CreateObject("Scripting.FileSystemObject") 
Set a = fs.CreateTextFile(filename, True) 'example (myfile.xml, True) 
a.writeline var1 
a.writeline var2 
a.Close