डेल्फी XE2 TZipFile: ज़िप संग्रह

Question

में एक फ़ाइल को प्रतिस्थापित करें मैं डेल्फी XE2/XE3 मानक सिस्टम। ज़िप इकाई के साथ एक ज़िप संग्रह में एक फ़ाइल (= पुराना हटाएं और नया जोड़ें) को प्रतिस्थापित करना चाहता हूं। लेकिन कोई प्रतिस्थापन/हटाए गए तरीके नहीं हैं। क्या किसी को यह पता है कि सभी फ़ाइलों को निकालने और उन्हें नए संग्रह में जोड़ने के बिना इसे कैसे प्राप्त किया जा सकता है?

मैं इस कोड है, लेकिन यह एक बार फिर "Document.txt" अगर यह पहले से ही मौजूद है कहते हैं:

var 
    ZipFile: TZipFile; 
    SS: TStringStream; 
const 
    ZipDocument = 'E:\document.zip'; 
begin 
    ZipFile := TZipFile.Create; //Zipfile: TZipFile 
    SS := TStringStream.Create('hello'); 
    try 
    if FileExists(ZipDocument) then 
     ZipFile.Open(ZipDocument, zmReadWrite) 
    else 
     ZipFile.Open(ZipDocument, zmWrite); 

    ZipFile.Add(SS, 'document.txt'); 

    ZipFile.Close; 
    finally 
    SS.Free; 
    ZipFile.Free; 
    end; 
end; 

नोट: मैंने पहले TPAbbrevia इस्तेमाल किया (जो काम किया है), लेकिन मैं चाहता हूँ अब डेल्फी की ज़िप इकाई का उपयोग करने के लिए। तो कृपया "किसी अन्य लाइब्रेरी का उपयोग करें" जैसे कुछ जवाब न दें। धन्यवाद।

Answer 1

मैं एब्रेविया की सलाह दूंगा क्योंकि मैं पक्षपातपूर्ण हूं :), आप पहले ही इसे जानते हैं, और इसे किसी भी हैक की आवश्यकता नहीं है। कि को छोड़कर, यहाँ हैक है:

type 
    TZipFileHelper = class helper for TZipFile 
    procedure Delete(FileName: string); 
    end; 

{ TZipFileHelper } 

procedure TZipFileHelper.Delete(FileName: string); 
var 
    i, j: Integer; 
    StartOffset, EndOffset, Size: UInt32; 
    Header: TZipHeader; 
    Buf: TBytes; 
begin 
    i := IndexOf(FileName); 
    if i <> -1 then begin 
    // Find extents for existing file in the file stream 
    StartOffset := Self.FFiles[i].LocalHeaderOffset; 
    EndOffset := Self.FEndFileData; 
    for j := 0 to Self.FFiles.Count - 1 do begin 
     if (Self.FFiles[j].LocalHeaderOffset > StartOffset) and 
     (Self.FFiles[j].LocalHeaderOffset <= EndOffset) then 
     EndOffset := Self.FFiles[j].LocalHeaderOffset; 
    end; 
    Size := EndOffset - StartOffset; 
    // Update central directory header data 
    Self.FFiles.Delete(i); 
    for j := 0 to Self.FFiles.Count - 1 do begin 
     Header := Self.FFiles[j]; 
     if Header.LocalHeaderOffset > StartOffset then begin 
     Header.LocalHeaderOffset := Header.LocalHeaderOffset - Size; 
     Self.FFiles[j] := Header; 
     end; 
    end; 
    // Remove existing file stream 
    SetLength(Buf, Self.FEndFileData - EndOffset); 
    Self.FStream.Position := EndOffset; 
    if Length(Buf) > 0 then 
     Self.FStream.Read(Buf[0], Length(Buf)); 
    Self.FStream.Size := StartOffset; 
    if Length(Buf) > 0 then 
     Self.FStream.Write(Buf[0], Length(Buf)); 
    Self.FEndFileData := Self.FStream.Position; 
    end; 
end; 

उपयोग:

ZipFile.Delete('document.txt'); 
ZipFile.Add(SS, 'document.txt');