Convert स्ट्रिंग $ हैश को "abc" -> {a} -> {b} -> {c} पर्ल

Question

में मैं इस तरह गतिशील नेस्टेड हैश refs है:

my $hash = { 'a' => { 'b' => { 'c' => 'value' } } }; 

मैं सेट करना चाहते हैं उपयोगकर्ता को "एबीसी कुछ" इनपुट करने की इजाजत देकर 'कुछ' का मूल्य।

अब हो रही मूल्य इस तरह किया जा सकता है:

my $keys = 'a.b.c'; 
my $v='something'; 
my $h = $hash; 
foreach my $k(split /\./, $keys) { 
    $h = $h->{$k}; 
} 
print $h; # "value" 

लेकिन यह कैसे मैं $v की कुंजी c का मान सेट हैं ताकि

print Dumper $hash; 

परिवर्तन को प्रतिबिंबित करेगा ? $h फ़ोरैच लूप के अंत में एक रेफरी नहीं है, इसलिए बदलना $hash में परिवर्तन को प्रतिबिंबित नहीं करेगा। मेरे सिर में गाँठ को हल करने के लिए कोई संकेत है?

Answer 1

कुछ इस तरह:

my $h = $hash; 
my @split_key = split /\./, $keys; 
my $last_key = pop @split_key; 
foreach my $k (@split_key) { 
    $h = $h->{$k}; 
} 
$h->{$last_key} = $v; 

Answer 2

use strictures; 
use Data::Diver qw(DiveVal); 

my ($hash, $path, $value) = (
    { 'a' => { 'b' => { 'c' => 'value' } } }, 
    'a.b.c', 
    'something', 
); 

DiveVal($hash, split /[.]/, $path) = $value; 
# { a => { b => { c => 'something' } } } 

Answer 3

बाहर पॉपिंग पिछले कुंजी wusses के लिए है! ;) इस समारोह के

sub dive :lvalue { 
    my $r = \shift; 
    $r = \(($$r)->{$_}) for @_; 
    return $$r; 
} 

my $data; 
my $key = 'a.b.c'; 
my $val = 'value'; 

dive($data, split /\./, $key) = $val; 

एक अधिक शक्तिशाली (और इस प्रकार से थोड़ा कठिन उपयोग करने के लिए) संस्करण Data::Diver द्वारा प्रदान की जाती है।

use Data::Diver qw(DiveVal); 

my $data; 
my $key = 'a.b.c'; 
my $val = 'value'; 

DiveVal($data //= {}, map \$_, split /\./, $key) = $val; 

(daxim के उपयोग बंद थोड़ा है।)