यहां एक ऐसी स्क्रिप्ट है जो इसे ठीक करने में सक्षम होने का दावा करती है।
Get admin rights to your local SQL Server Express with this simple script
Download link to the script
विवरण
यह आदेश स्क्रिप्ट आप आसानी से एक स्थानीय एसक्यूएल सर्वर उदाहरण के सिस्टम प्रशासक भूमिका के लिए अपने आप को जोड़ने के लिए अनुमति देता है। आपको विंडोज स्थानीय व्यवस्थापक समूह का सदस्य होना चाहिए, या उस उपयोगकर्ता के क्रेडेंशियल्स तक पहुंच होनी चाहिए। स्क्रिप्ट एसक्यूएल सर्वर 2005 और बाद में समर्थन करता है।
स्क्रिप्ट सबसे उपयोगी है यदि आप किसी डेवलपर द्वारा SQL सर्वर 2008 एक्सप्रेस का उपयोग करने का प्रयास कर रहे हैं जो किसी और द्वारा स्थापित किया गया था। इस स्थिति में आपके पास आमतौर पर SQL Server 2008 एक्सप्रेस इंस्टेंस के लिए व्यवस्थापकीय अधिकार नहीं होंगे, क्योंकि डिफ़ॉल्ट रूप से केवल SQL सर्वर 2008 स्थापित करने वाले व्यक्ति को व्यवस्थापकीय विशेषाधिकार प्रदान किए जाते हैं।
SQL सर्वर 2008 एक्सप्रेस स्थापित करने वाले उपयोगकर्ता SQL सर्वर प्रबंधन स्टूडियो का उपयोग आपके लिए आवश्यक विशेषाधिकार प्रदान करने के लिए कर सकते हैं। लेकिन क्या यदि SQL सर्वर प्रबंधन स्टूडियो स्थापित नहीं किया गया था? या बदतर उपयोगकर्ता स्थापित करने के लिए अब और उपलब्ध नहीं है?
यह स्क्रिप्ट केवल कुछ क्लिक में समस्या को हल करता है!
ध्यान दें: आप एक 'उदाहरण के नाम' के साथ बैट फ़ाइल प्रदान करना होगा (शायद 'MSSQLSERVER' होने जा रहा - लेकिन यह नहीं हो सकता है): आप पहली बार में निम्नलिखित चलाकर मूल्य प्राप्त कर सकते हैं "Microsoft SQL सर्वर प्रबंधन कंसोल":
SELECT @@servicename
फिर जब बैट फ़ाइल 'एसक्यूएल उदाहरण के नाम' के लिए संकेत देता का उपयोग करने के परिणाम की प्रतिलिपि बनाएँ।
@echo off
rem
rem ****************************************************************************
rem
rem Copyright (c) Microsoft Corporation. All rights reserved.
rem This code is licensed under the Microsoft Public License.
rem THIS CODE IS PROVIDED *AS IS* WITHOUT WARRANTY OF
rem ANY KIND, EITHER EXPRESS OR IMPLIED, INCLUDING ANY
rem IMPLIED WARRANTIES OF FITNESS FOR A PARTICULAR
rem PURPOSE, MERCHANTABILITY, OR NON-INFRINGEMENT.
rem
rem ****************************************************************************
rem
rem CMD script to add a user to the SQL Server sysadmin role
rem
rem Input: %1 specifies the instance name to be modified. Defaults to SQLEXPRESS.
rem %2 specifies the principal identity to be added (in the form "<domain>\<user>").
rem If omitted, the script will request elevation and add the current user (pre-elevation) to the sysadmin role.
rem If provided explicitly, the script is assumed to be running elevated already.
rem
rem Method: 1) restart the SQL service with the '-m' option, which allows a single connection from a box admin
rem (the box admin is temporarily added to the sysadmin role with this start option)
rem 2) connect to the SQL instance and add the user to the sysadmin role
rem 3) restart the SQL service for normal connections
rem
rem Output: Messages indicating success/failure.
rem Note that if elevation is done by this script, a new command process window is created: the output of this
rem window is not directly accessible to the caller.
rem
rem
setlocal
set sqlresult=N/A
if .%1 == . (set /P sqlinstance=Enter SQL instance name, or default to SQLEXPRESS:) else (set sqlinstance=%1)
if .%sqlinstance% == . (set sqlinstance=SQLEXPRESS)
if /I %sqlinstance% == MSSQLSERVER (set sqlservice=MSSQLSERVER) else (set sqlservice=MSSQL$%sqlinstance%)
if .%2 == . (set sqllogin="%USERDOMAIN%\%USERNAME%") else (set sqllogin=%2)
rem remove enclosing quotes
for %%i in (%sqllogin%) do set sqllogin=%%~i
@echo Adding '%sqllogin%' to the 'sysadmin' role on SQL Server instance '%sqlinstance%'.
@echo Verify the '%sqlservice%' service exists ...
set srvstate=0
for /F "usebackq tokens=1,3" %%i in (`sc query %sqlservice%`) do if .%%i == .STATE set srvstate=%%j
if .%srvstate% == .0 goto existerror
rem
rem elevate if <domain/user> was defaulted
rem
if NOT .%2 == . goto continue
echo new ActiveXObject("Shell.Application").ShellExecute("cmd.exe", "/D /Q /C pushd \""+WScript.Arguments(0)+"\" & \""+WScript.Arguments(1)+"\" %sqlinstance% \""+WScript.Arguments(2)+"\"", "", "runas"); >"%TEMP%\addsysadmin{7FC2CAE2-2E9E-47a0-ADE5-C43582022EA8}.js"
call "%TEMP%\addsysadmin{7FC2CAE2-2E9E-47a0-ADE5-C43582022EA8}.js" "%cd%" %0 "%sqllogin%"
del "%TEMP%\addsysadmin{7FC2CAE2-2E9E-47a0-ADE5-C43582022EA8}.js"
goto :EOF
:continue
rem
rem determine if the SQL service is running
rem
set srvstarted=0
set srvstate=0
for /F "usebackq tokens=1,3" %%i in (`sc query %sqlservice%`) do if .%%i == .STATE set srvstate=%%j
if .%srvstate% == .0 goto queryerror
rem
rem if required, stop the SQL service
rem
if .%srvstate% == .1 goto startm
set srvstarted=1
@echo Stop the '%sqlservice%' service ...
net stop %sqlservice%
if errorlevel 1 goto stoperror
:startm
rem
rem start the SQL service with the '-m' option (single admin connection) and wait until its STATE is '4' (STARTED)
rem also use trace flags as follows:
rem 3659 - log all errors to errorlog
rem 4010 - enable shared memory only (lpc:)
rem 4022 - do not start autoprocs
rem
@echo Start the '%sqlservice%' service in maintenance mode ...
sc start %sqlservice% -m -T3659 -T4010 -T4022 >nul
if errorlevel 1 goto startmerror
:checkstate1
set srvstate=0
for /F "usebackq tokens=1,3" %%i in (`sc query %sqlservice%`) do if .%%i == .STATE set srvstate=%%j
if .%srvstate% == .0 goto queryerror
if .%srvstate% == .1 goto startmerror
if NOT .%srvstate% == .4 goto checkstate1
rem
rem add the specified user to the sysadmin role
rem access tempdb to avoid a misleading shutdown error
rem
@echo Add '%sqllogin%' to the 'sysadmin' role ...
for /F "usebackq tokens=1,3" %%i in (`sqlcmd -S np:\\.\pipe\SQLLocal\%sqlinstance% -E -Q "create table #foo (bar int); declare @rc int; execute @rc = sp_addsrvrolemember '$(sqllogin)', 'sysadmin'; print 'RETURN_CODE : '+CAST(@rc as char)"`) do if .%%i == .RETURN_CODE set sqlresult=%%j
rem
rem stop the SQL service
rem
@echo Stop the '%sqlservice%' service ...
net stop %sqlservice%
if errorlevel 1 goto stoperror
if .%srvstarted% == .0 goto exit
rem
rem start the SQL service for normal connections
rem
net start %sqlservice%
if errorlevel 1 goto starterror
goto exit
rem
rem handle unexpected errors
rem
:existerror
sc query %sqlservice%
@echo '%sqlservice%' service is invalid
goto exit
:queryerror
@echo 'sc query %sqlservice%' failed
goto exit
:stoperror
@echo 'net stop %sqlservice%' failed
goto exit
:startmerror
@echo 'sc start %sqlservice% -m' failed
goto exit
:starterror
@echo 'net start %sqlservice%' failed
goto exit
:exit
if .%sqlresult% == .0 (@echo '%sqllogin%' was successfully added to the 'sysadmin' role.) else (@echo '%sqllogin%' was NOT added to the 'sysadmin' role: SQL return code is %sqlresult%.)
endlocal
pause
क्या आप SQL सर्वर प्रमाणीकरण या Windows प्रमाणीकरण के माध्यम से कनेक्ट करने का प्रयास कर रहे हैं? –
विंडोज प्रमाणीकरण (शीर्षक देखें)। मैं सफलतापूर्वक कनेक्ट कर रहा हूँ। त्रुटियां व्यवस्थापक कार्यों को करने का प्रयास करने से आती हैं। – SkonJeet