एक tfilestream

Question

पर बिटमैप्स लिखना/पढ़ना मैंने खोजा और खोजा है और ऐसा कुछ भी नहीं ढूंढ रहा है जो वर्णन करता है कि मैं डेल्फी कोड में क्या करना चाहता हूं। सोल्यूटीन कभी-कभी नज़दीक होते हैं लेकिन मुझे पता लगाने के लिए पर्याप्त नहीं होते हैं। तो यहां मैं पूछ रहा हूं ..

मेरे पास कई बिटमैप हैं जो मैं स्क्रीनशॉट से पुनः सहेज रहा हूं। मैं जो कर रहा हूं वह bitmaps_001.bmp पर सहेज रहा है, लेकिन इसमें बहुत अधिक संग्रहण स्थान लगता है, इसलिए मैंने नियमित रूप से bitmaps_001.png के रूप में सहेजने के लिए अपग्रेड किया, और यह और भी अधिक जगह बचाता है, लेकिन अब मैं एक फ़ाइल को सहेजना चाहता हूं, एक tfilestream, और एक tprogressbar का उपयोग कर इसे से पढ़ा है कि मैं स्क्रीन पर छवियों के रूप में बाएं/दाएं खींच सकते हैं।

मूल रूप से, मैं निम्नलिखित पूरा करने के लिए कोशिश कर रहा हूँ:

procedure SaveBMPtoStream(st: tfilestream; bmp: tbitmap); 
procedure ReadBMPfrStream(st: tfilestream; bmp: tbitmap; bnum: integer); 

अब तक कोड (नीचे)

काम करता है के रूप में है, (यह लिखते हैं और एक tbutton की प्रेस में एक बिटमैप छवि में पढ़ता है), लेकिन मैं केवल एक बिटमैप छवि लिख सकते हैं। मुझे रीयलटाइम में tfilestream के लिए आवश्यक प्रति सत्र जितनी छवियां लिखनी होंगी, संभवतः एक टीटीमर नियंत्रण का उपयोग करके और जब तक मैं स्टॉप tbutton दबाता हूं तब तक इसे कई छवियों को लिखने दें। इसे हल करने के लिए नीचे दिए गए कोड को संशोधित करने के लिए मैं क्या कर सकता हूं? धन्यवाद।

मैं विंडोज एक्सपी चला रहा हूं, एनटीएफएस फाइल सिस्टम के साथ बाहरी यूएसबी 3.0 1 टीबी ड्राइव से जुड़ा हुआ है।

type 
    TMS = TFileStream; 
var 
    MS: TMS; 
    pos: int64; // bnum for 0-99,999 images. 
    sz: integer; // size of the image/stream ? 

//write bitmaps to stream 
procedure SaveBMPtoStream(ms: TMS; Bmp: TBitmap; bnum: integer); 
begin 
    // create (or append to) stream 
    if fileexists('d:\streams\s.stm') then MS := TFileStream.Create('d:\streams\s.stm', fmOpenReadWrite) 
    else MS := TFileStream.Create('d:\streams\s.stm', fmCreate); 
    //sz:=MS.Size; pos:=ms.Position; 
    bmp.SaveToStream(MS); 
    // free stream 
    ms.free; 
end; 

//read bitmaps from stream 
procedure ReadBMPfrStream(ms: TMS; Bmp: TBitmap; bnum: integer); 
begin 
    // open stream. 
    MS := TFileStream.Create ('d:\streams\s.stm', fmOpenReadWrite); 
    // read in bitmap from stream 
    //sz:=MS.Size; pos:=ms.Position; 
    bmp.LoadFromStream(MS); 
    // free stream 
    ms.free; 
end; 

Answer 1

Function LoadBMPFromStream(const fn: String; Bmp: TBitmap; Nr: Integer):Boolean; 
var // Nr is 0 based first Bitmap=0 
    fs: TFileStream; 
    ms: TMemoryStream; 
    intNr: Integer; 
    pos: Cardinal; 
    size: DWord; 
begin 
    intNr := 0; 
    if fileexists(fn) then 
    begin 
    Result := true; 
    fs := TFileStream.Create(fn, fmOpenRead or fmShareDenyNone); 
    try 
     fs.Read(size, SizeOf(DWord)); // Read Size of first Bitmap 
     while (Nr > intNr) and (fs.Position < fs.size) do 
     begin 
     fs.Seek(size, soFromCurrent); 
     fs.Read(size, SizeOf(DWord)); // Read Size of Bitmap with intNr 
     inc(intNr); 
     end; 
     if fs.Position < fs.size then 
     begin 
     ms := TMemoryStream.Create; 
     try 
      ms.CopyFrom(fs, size); 
      ms.Position := 0; 
      Bmp.LoadFromStream(ms); 
     finally 
      ms.Free; 
     end; 
     end 
     else Result := false; 
    finally 
     fs.Free; 
    end; 

    end; 
end; 


procedure SaveBMPtoStream(const fn: String; Bmp: TBitmap); 
var 
    fs: TFileStream; 
    ms: TMemoryStream; 
    pos: Cardinal; 
    size: DWord; 
begin 
    if fileexists(fn) then 
    begin 
    fs := TFileStream.Create(fn, fmOpenReadWrite or fmShareDenyNone); 
    fs.Seek(0, soEnd); 
    end 
    else 
    begin 
    fs := TFileStream.Create(fn, fmCreate or fmShareDenyNone); 
    end; 
    try 
    ms := TMemoryStream.Create; 
    try 
     Bmp.SaveToStream(ms); 
     size := ms.size; 
     ms.Position := 0; 
     fs.Write(size, SizeOf(DWord)); // Write Size of next Bitmap first 
     fs.CopyFrom(ms, size); 
    finally 
     ms.Free; 
    end; 
    finally 
    fs.Free; 
    end; 

end; 

procedure TForm6.Button2Click(Sender: TObject); 
begin 
    // load first Picture 
    LoadBMPFromStream('C:\temp\test.str', Image3.picture.bitmap, 0); 
    // load third picture 
    // LoadBMPFromStream('C:\temp\test.str', Image3.picture.bitmap, 2); 
end; 

procedure TForm6.Button1Click(Sender: TObject); 
begin 
    SaveBMPtoStream('C:\temp\test.str', Image1.picture.bitmap); 
    SaveBMPtoStream('C:\temp\test.str', Image2.picture.bitmap); 
    SaveBMPtoStream('C:\temp\test.str', Image1.picture.bitmap); 
end; 

Answer 2

आप सभी छवियों को एक ही फ़ाइल में सहेजना चाहते हैं? आपका सबसे आसान विकल्प तब 0 संपीड़न (केवल स्टोर) के साथ 7zip फ़ाइल का उपयोग करेगा, यह आपके लिए संग्रह से फ़ाइलों की अनुक्रमण/बचत/पुनर्प्राप्ति का प्रबंधन करेगा। http://www.rg-software.de/rg/index.php?option=com_content&view=article&id=29&Itemid=51

तुम भी अब फिर से केवल बिटमैप्स का उपयोग कर, 7zip में एक तेजी से संपीड़न सेटिंग का उपयोग करते समय की कोशिश कर सकते, यह शायद पीएनजी की तुलना में बेहतर गति को प्राप्त होगा:

यहाँ एक अच्छा मुक्त घटक है कि यह कर सकते हैं है।