डेल्फी रिकॉर्ड में बिट-फ़ील्ड का अनुकरण कैसे करें?

Question

मैं के रूप में यह सी

में है

उन दिलचस्पी के लिए है कि एक ही लेआउट शामिल डेल्फी में एक रिकार्ड घोषित करने के लिए करना चाहते हैं: इस रिकॉर्ड Windows OS की LDT_ENTRY रिकॉर्ड में एक संघ का हिस्सा है। (मुझे डेल्फी में इस रिकॉर्ड का उपयोग करने की आवश्यकता है क्योंकि मैं डेल्फी में एक एक्सबॉक्स एमुलेटर पर काम कर रहा हूं - प्रोजेक्ट डीएक्सबीएक्स को स्रोत फोर्ज पर देखें)।

struct 
    { 
     DWORD BaseMid : 8; 
     DWORD Type : 5; 
     DWORD Dpl : 2; 
     DWORD Pres : 1; 
     DWORD LimitHi : 4; 
     DWORD Sys : 1; 
     DWORD Reserved_0 : 1; 
     DWORD Default_Big : 1; 
     DWORD Granularity : 1; 
     DWORD BaseHi : 8; 
    } 
    Bits; 

जहाँ तक मुझे पता है, वहाँ कोई डेल्फी में संभव बिट क्षेत्र हैं:

वैसे भी, सवाल में रिकॉर्ड के रूप में परिभाषित किया गया है। उम्मीद 4. मैं चाहूँगा के बजाय यह आकार 10 बाइट्स बन जाता है, पता करने के लिए मैं रिकॉर्ड कैसे घोषित चाहिए, ताकि मैं एक ही लेआउट के साथ एक रिकॉर्ड मिलता है: मैं यह कोशिश की थी:

Bits = record 
     BaseMid: Byte; // 8 bits 
     _Type: 0..31; // 5 bits 
     Dpl: 0..3; // 2 bits 
     Pres: Boolean; // 1 bit 
     LimitHi: 0..15; // 4 bits 
     Sys: Boolean; // 1 bit 
     Reserved_0: Boolean; // 1 bit 
     Default_Big: Boolean; // 1 bit 
     Granularity: Boolean; // 1 bit 
     BaseHi: Byte; // 8 bits 
    end; 

लेकिन अफसोस , एक ही आकार, और एक ही सदस्य। Preterrably गेटटर/सेटर्स के भार के बिना।

टीआईए।

Answer 1

सभी को धन्यवाद!

RBits = record 
public 
    BaseMid: BYTE; 
private 
    Flags: WORD; 
    function GetBits(const aIndex: Integer): Integer; 
    procedure SetBits(const aIndex: Integer; const aValue: Integer); 
public 
    BaseHi: BYTE; 
    property _Type: Integer index $0005 read GetBits write SetBits; // 5 bits at offset 0 
    property Dpl: Integer index $0502 read GetBits write SetBits; // 2 bits at offset 5 
    property Pres: Integer index $0701 read GetBits write SetBits; // 1 bit at offset 7 
    property LimitHi: Integer index $0804 read GetBits write SetBits; // 4 bits at offset 8 
    property Sys: Integer index $0C01 read GetBits write SetBits; // 1 bit at offset 12 
    property Reserved_0: Integer index $0D01 read GetBits write SetBits; // 1 bit at offset 13 
    property Default_Big: Integer index $0E01 read GetBits write SetBits; // 1 bit at offset 14 
    property Granularity: Integer index $0F01 read GetBits write SetBits; // 1 bit at offset 15 
end; 

सूचकांक इस प्रकार एन्कोड किया गया है: (BitOffset shl 8) + NrBits

इस जानकारी के आधार पर, मैं करने के लिए इस कम कर दिया। कहाँ 1 < = NrBits < = 32 और 0 < = BitOffset < = 31

अब, मैं मिलता है और इस प्रकार इन बिट्स सेट कर सकते हैं:

{$OPTIMIZATION ON} 
{$OVERFLOWCHECKS OFF} 
function RBits.GetBits(const aIndex: Integer): Integer; 
var 
    Offset: Integer; 
    NrBits: Integer; 
    Mask: Integer; 
begin 
    NrBits := aIndex and $FF; 
    Offset := aIndex shr 8; 

    Mask := ((1 shl NrBits) - 1); 

    Result := (Flags shr Offset) and Mask; 
end; 

procedure RBits.SetBits(const aIndex: Integer; const aValue: Integer); 
var 
    Offset: Integer; 
    NrBits: Integer; 
    Mask: Integer; 
begin 
    NrBits := aIndex and $FF; 
    Offset := aIndex shr 8; 

    Mask := ((1 shl NrBits) - 1); 
    Assert(aValue <= Mask); 

    Flags := (Flags and (not (Mask shl Offset))) or (aValue shl Offset); 
end; 

सुंदर गंधा, आपको नहीं लगता कि?!? !

पीएस: रुडी वेल्थ्यूस में अब अपने उत्कृष्ट "Pitfalls of converting"-article में इसका एक संशोधित संस्करण शामिल है।

Answer 2

ठीक है, आपको मूल रूप से बिट-मैनिपुलेशन के साथ गंदा होने की आवश्यकता है।

क्यों, विशेष रूप से, आपको उस संरचना को बनाए रखने की आवश्यकता है?

यदि आपको केवल एक विरासत कार्यक्रम से बात करने की आवश्यकता है जो या तो इस बोली (टीसीपी/आईपी या इसी तरह) में बात करती है, या डेटा को इस तरीके से (फाइलें इत्यादि) में स्टोर करती है, तो मैं एक सामान्य डेल्फी संरचना को मैप करूँगा एक बिट संस्करण संगत। दूसरे शब्दों में, मैं स्मृति में सामान्य रूप से संरचित डेल्फी संरचना का उपयोग करता हूं, और उस संरचना को संगत तरीके से लिखने और पढ़ने के लिए कोड लिखता हूं।

यदि आपको स्मृति को सहेजने की आवश्यकता है, तो मैं गेटर्स और सेटर्स बनाउंगा जो आंतरिक पूर्णांक या इसी तरह के बिट्स में हेरफेर करते हैं। इसका प्रदर्शन प्रभाव होगा, लेकिन मूल सी प्रोग्राम के मुकाबले ज्यादा कुछ नहीं होगा, केवल अंतर यह है कि सी संस्करण में कंपाइलर जादू द्वारा बिट-मैनिपुलेशन जोड़ा जाएगा, जबकि आपको इसे स्वयं लिखना होगा।

यदि आपके पास स्मृति में कई रिकॉर्ड नहीं हैं, और किसी अन्य प्रोग्राम से बात करने की आवश्यकता नहीं है, तो मैं एक प्राकृतिक डेल्फी संरचना का उपयोग करूंगा। उच्च प्रदर्शन के लिए व्यापार-बंद अधिक स्मृति का उपयोग किया जाएगा।

लेकिन यह सब आपके मानदंडों पर निर्भर करता है।

किसी भी मामले में, आप सी संकलक के रूप में आपके लिए एक ही काम करने में डेल्फी कंपाइलर से बात करने में सक्षम नहीं होंगे।

पैक किया गया रिकॉर्ड, जो किसी अन्य द्वारा सुझाया गया है, ऐसा नहीं करता है, और इसका मतलब कभी नहीं था। यह केवल 32-बिट सीमाओं और समान पर पूर्णांक लगाने के लिए संरेखण पैडिंग को हटा देगा, लेकिन एकाधिक फ़ील्ड को एक बाइट में पैक नहीं करेगा।

ध्यान दें कि ऐसा करने का एक आम तरीका डेल्फी सेट्स के माध्यम से है, जो आंतरिक रूप से बिट-फ़ील्ड का उपयोग कर कार्यान्वित कर रहे हैं। फिर, आपके पास सी संस्करण से अलग कोड होगा।

Answer 3

Rudy's Delphi Corner डेल्फी और सी/सी ++ इंटरऑपरेबिलिटी के बारे में मुझे पता है सबसे अच्छा संसाधन है। डेल्फी में सी/सी ++ एपीआई का उपयोग करते समय उनके Pitfalls of conversion को बहुत कुछ पढ़ना चाहिए। जिस अध्याय में आप सबसे अधिक रुचि रखते हैं वह Records and alignment -> Bitfields है, लेकिन मैं आपको पूरी चीज को नीचे से नीचे, दो बार पढ़ने के लिए आग्रह करता हूं। अन्य लेख निश्चित रूप से समय निवेश के लायक हैं।

Answer 4

ठीक है, मेरा थोड़ा हेरफेर थोड़ा जंगली है, इसलिए मैं बाइट को उलट सकता था। लेकिन नीचे दिया गया कोड सामान्य विचार देता है:

type 
    TBits = record 
    private 
    FBaseMid  : Byte; 
    FTypeDplPres : Byte; 
    FLimitHiSysEa: Byte; 
    FBaseHi  : Byte; 

    function GetType: Byte; 
    procedure SetType(const AType: Byte); 
    function GetDpl: Byte; 
    procedure SetDbl(const ADpl: Byte); 
    function GetBit1(const AIndex: Integer): Boolean; 
    procedure SetBit1(const AIndex: Integer; const AValue: Boolean); 
    function GetLimitHi: Byte; 
    procedure SetLimitHi(const AValue: Byte); 
    function GetBit2(const AIndex: Integer): Boolean; 
    procedure SetBit2(const AIndex: Integer; const AValue: Boolean); 

    public 
    property BaseMid: Byte read FBaseMid write FBaseMid; 
    property &Type: Byte read GetType write SetType; // 0..31 
    property Dpl: Byte read GetDpl write SetDbl; // 0..3 
    property Pres: Boolean index 128 read GetBit1 write SetBit1; 
    property LimitHi: Byte read GetLimitHi write SetLimitHi; // 0..15 

    property Sys: Boolean index 16 read GetBit2 write SetBit2; 
    property Reserved0: Boolean index 32 read GetBit2 write SetBit2; 
    property DefaultBig: Boolean index 64 read GetBit2 write SetBit2; 
    property Granularity: Boolean index 128 read GetBit2 write SetBit2; 
    property BaseHi: Byte read FBaseHi write FBaseHi; 
    end; 

    function TBits.GetType: Byte; 
    begin 
    Result := (FTypeDplPres shr 3) and $1F; 
    end; 

    procedure TBits.SetType(const AType: Byte); 
    begin 
    FTypeDplPres := (FTypeDplPres and $07) + ((AType and $1F) shr 3); 
    end; 

    function TBits.GetDpl: Byte; 
    begin 
    Result := (FTypeDplPres and $06) shr 1; 
    end; 

    procedure TBits.SetDbl(const ADpl: Byte); 
    begin 
    FTypeDblPres := (FTypeDblPres and $F9) + ((ADpl and $3) shl 1); 
    end; 

    function TBits.GetBit1(const AIndex: Integer): Boolean; 
    begin 
    Result := FTypeDplPres and AIndex = AIndex; 
    end; 

    procedure TBits.SetBit1(const AIndex: Integer; const AValue: Boolean); 
    begin 
    if AValue then 
     FTypeDblPres := FTypeDblPres or AIndex 
    else 
     FTypeDblPres := FTypeDblPres and not AIndex; 
    end; 

    function TBits.GetLimitHi: Byte; 
    begin 
    Result := (FLimitHiSysEa shr 4) and $0F; 
    end; 

    procedure TBits.SetLimitHi(const AValue: Byte); 
    begin 
    FLimitHiSysEa := (FLimitHiSysEa and $0F) + ((AValue and $0F) shr 4); 
    end; 

    function TBits.GetBit2(const AIndex: Integer): Boolean; 
    begin 
    Result := FLimitHiSysEa and AIndex = AIndex; 
    end; 

    procedure TBits.SetBit2(const AIndex: Integer; const AValue: Boolean); 
    begin 
    if AValue then 
     FLimitHiSysEa := FLimitHiSysEa or AIndex 
    else 
     FLimitHiSysEa := FLimitHiSysEa and not AIndex; 
    end;