चयन आयत जैसे कार्यालय XP विषय के साथ एक सूची बॉक्स कैसे बनाएं?

Question

Office XP शैली के साथ एक केंद्रित/चयनित सूचीबॉक्स आइटम दिखाने का सबसे आसान और साफ तरीका क्या होगा?

इस नमूना छवि विचार को दिखाने के लिए अधिक स्पष्ट:

मुझे लगता है मैं लिस्टबॉक्स शैली या तो lbOwnerDrawFixed या lbOwnerDrawVariable और फिर OnDrawItem ईवेंट को संशोधित करने के लिए सेट की आवश्यकता है?

यह वह जगह है जहाँ मैं कर रहा हूँ अटक, मैं वास्तव में यकीन है कि क्या कोड में वहाँ लिखने के लिए कर रहा हूँ, अब तक मैंने कोशिश की:

procedure TForm1.ListBox1DrawItem(Control: TWinControl; Index: Integer; 
    Rect: TRect; State: TOwnerDrawState); 
begin 
    with (Control as TListBox).Canvas do 
    begin 
    if odSelected in State then 
    begin 
     Brush.Color := $00FCDDC0; 
     Pen.Color := $00FF9933; 
     FillRect(Rect); 
    end; 

    TextOut(Rect.Left, Rect.Top, TListBox(Control).Items[Index]); 
    end; 
end; 

मैं जाना जाता है चाहिए कि काम नहीं होगा, मैं अजीब के सभी प्रकार के विवरण अधिक महत्वपूर्ण बात यह है कि मैं क्या यह काम करने के लिए बदलने की जरूरत है

मैं गलत क्या कर रहा हूँ,: बातों पर जा रहे हैं?

धन्यवाद।

Answer 1

आप विभिन्न राज्यों के लिए आइटम पेंट करना भूल गए हैं। आपको यह निर्धारित करने की आवश्यकता है कि वर्तमान में आइटम किस स्थिति में है और इसके अनुसार इसे आकर्षित करें।

आपकी तस्वीर पर आपके पास क्या है, आप इस तरह से प्राप्त कर सकते हैं। हालांकि यह अच्छी तरह से लग रहा है नहीं करता है तो आप एकाधिक चयन करें सक्षम है और एक से अधिक आइटम का चयन किया है:

procedure TForm1.ListBox1DrawItem(Control: TWinControl; Index: Integer; 
    Rect: TRect; State: TOwnerDrawState); 
var 
    Offset: Integer; 
begin 
    with (Control as TListBox) do 
    begin 
    Canvas.Font.Color := Font.Color; 
    if (odSelected in State) then 
    begin 
     Canvas.Pen.Color := $00FF9932; 
     Canvas.Brush.Color := $00FDDDC0; 
    end 
    else 
    begin 
     Canvas.Pen.Color := Color; 
     Canvas.Brush.Color := Color; 
    end; 
    Canvas.Rectangle(Rect); 
    Canvas.Brush.Style := bsClear; 
    Offset := (Rect.Bottom - Rect.Top - Canvas.TextHeight(Items[Index])) div 2; 
    Canvas.TextOut(Rect.Left + Offset + 2, Rect.Top + Offset, Items[Index]); 
    end; 
end; 

और ItemHeight सेट से 16 के साथ परिणाम:

बोनस - निरंतर चयन :

यहां एक सतत चयन लागू करने का एक कठिन समाधान है। सिद्धांत पहले की तरह आइटम को आकर्षित करना है, लेकिन पिछले और अगले आइटम की चयन स्थिति के आधार पर किसी रंग की रेखाओं के साथ आइटम की सीमा शीर्ष और निचली रेखाओं को ओवरराइड करना है। इसके अलावा, वर्तमान आइटम के बाहर भी प्रस्तुत किया जाना चाहिए, क्योंकि आइटम चयन स्वाभाविक रूप से पड़ोसी वस्तुओं को पुनर्निर्मित करने के लिए नहीं बुलाता है। इस प्रकार क्षैतिज रेखाओं को ऊपर एक पिक्सेल चित्रित किया जाता है और वर्तमान आइटम सीमाओं के नीचे एक पिक्सेल (इन पंक्तियों के रंग सापेक्ष चयन राज्यों पर भी निर्भर करता है)।

यहां पर अजीब अजीब वस्तु वस्तुओं का उपयोग प्रत्येक आइटम की चयनित स्थिति को संग्रहीत करने के लिए है। मैंने ऐसा किया, क्योंकि ड्रैग & ड्रॉप आइटम चयन का उपयोग करते समय, Selected संपत्ति तब तक वास्तविक स्थिति नहीं लौटाती जब तक कि आप माउस बटन को छोड़ नहीं देते। सौभाग्य से, OnDrawItem पाठ्यक्रम की स्थिति वास्तविक स्थिति के साथ आग लगती है, इसलिए एक कामकाज के रूप में मैंने OnDrawItem घटना से इन राज्यों को संग्रहित किया है।

महत्वपूर्ण:

ध्यान दें, कि मैं वास्तविक चयन राज्य स्टोर करने के लिए है, इसलिए सावधान रहना, और जब आप कुछ और के लिए आइटम वस्तुओं का उपयोग कर रहे, इस वास्तविक स्टोर आइटम वस्तुओं का उपयोग कर रहा उदाहरण के लिए राज्यों बूलियन की एक सरणी में।

procedure TForm1.ListBox1DrawItem(Control: TWinControl; Index: Integer; 
    Rect: TRect; State: TOwnerDrawState); 
const 
    SelBackColor = $00FDDDC0; 
    SelBorderColor = $00FF9932; 
var 
    Offset: Integer; 
    ItemSelected: Boolean; 
begin 
    with (Control as TListBox) do 
    begin 
    Items.Objects[Index] := TObject((odSelected in State));  

    if (odSelected in State) then 
    begin 
     Canvas.Pen.Color := SelBorderColor; 
     Canvas.Brush.Color := SelBackColor; 
     Canvas.Rectangle(Rect); 
    end 
    else 
    begin 
     Canvas.Pen.Color := Color; 
     Canvas.Brush.Color := Color; 
     Canvas.Rectangle(Rect); 
    end; 

    if MultiSelect then 
    begin 
     if (Index > 0) then 
     begin 
     ItemSelected := Boolean(ListBox1.Items.Objects[Index - 1]); 
     if ItemSelected then 
     begin 
      if (odSelected in State) then 
      begin 
      Canvas.Pen.Color := SelBackColor; 
      Canvas.MoveTo(Rect.Left + 1, Rect.Top); 
      Canvas.LineTo(Rect.Right - 1, Rect.Top); 
      end 
      else 
      Canvas.Pen.Color := SelBorderColor; 
     end 
     else 
      Canvas.Pen.Color := Color; 
     Canvas.MoveTo(Rect.Left + 1, Rect.Top - 1); 
     Canvas.LineTo(Rect.Right - 1, Rect.Top - 1); 
     end; 

     if (Index < Items.Count - 1) then 
     begin 
     ItemSelected := Boolean(ListBox1.Items.Objects[Index + 1]); 
     if ItemSelected then 
     begin 
      if (odSelected in State) then 
      begin 
      Canvas.Pen.Color := SelBackColor; 
      Canvas.MoveTo(Rect.Left + 1, Rect.Bottom - 1); 
      Canvas.LineTo(Rect.Right - 1, Rect.Bottom - 1); 
      end 
      else 
      Canvas.Pen.Color := SelBorderColor; 
     end 
     else 
      Canvas.Pen.Color := Color; 
     Canvas.MoveTo(Rect.Left + 1, Rect.Bottom); 
     Canvas.LineTo(Rect.Right - 1, Rect.Bottom); 
     end; 
    end; 

    Offset := (Rect.Bottom - Rect.Top - Canvas.TextHeight(Items[Index])) div 2; 
    Canvas.Brush.Style := bsClear; 
    Canvas.Font.Color := Font.Color; 
    Canvas.TextOut(Rect.Left + Offset + 2, Rect.Top + Offset, Items[Index]); 
    end; 
end; 

और परिणाम:

Answer 2

आपको फ़ंक्शन में पारित राज्य चर के मान को देखने की आवश्यकता है। यह आपको बताता है कि आइटम का चयन किया गया है या नहीं और फिर आप ब्रश और पेन को उचित रूप से सेट कर सकते हैं।